mirror of
https://github.com/python/cpython.git
synced 2025-08-31 22:18:28 +00:00
48ede6b8f6
The activation scripts generated by venv were inconsistent in how they changed the shell's prompt. Some used `__VENV_PROMPT__` exclusively, some used `__VENV_PROMPT__` if it was set even though by default `__VENV_PROMPT__` is always set and the fallback matched the default, and one ignored `__VENV_PROMPT__` and used `__VENV_NAME__` instead (and even used a differing format to the default prompt). This change now has all activation scripts use `__VENV_PROMPT__` only and relies on the fact that venv sets that value by default. The color of the customization is also now set in fish to the blue from the Python logo for as hex color support is built into that shell (much like PowerShell where the built-in green color is used).
64 lines
1.9 KiB
Fish
64 lines
1.9 KiB
Fish
# This file must be used with ". bin/activate.fish" *from fish* (http://fishshell.org);
|
|
# you cannot run it directly.
|
|
|
|
function deactivate -d "Exit virtualenv and return to normal shell environment"
|
|
# reset old environment variables
|
|
if test -n "$_OLD_VIRTUAL_PATH"
|
|
set -gx PATH $_OLD_VIRTUAL_PATH
|
|
set -e _OLD_VIRTUAL_PATH
|
|
end
|
|
if test -n "$_OLD_VIRTUAL_PYTHONHOME"
|
|
set -gx PYTHONHOME $_OLD_VIRTUAL_PYTHONHOME
|
|
set -e _OLD_VIRTUAL_PYTHONHOME
|
|
end
|
|
|
|
if test -n "$_OLD_FISH_PROMPT_OVERRIDE"
|
|
functions -e fish_prompt
|
|
set -e _OLD_FISH_PROMPT_OVERRIDE
|
|
functions -c _old_fish_prompt fish_prompt
|
|
functions -e _old_fish_prompt
|
|
end
|
|
|
|
set -e VIRTUAL_ENV
|
|
if test "$argv[1]" != "nondestructive"
|
|
# Self-destruct!
|
|
functions -e deactivate
|
|
end
|
|
end
|
|
|
|
# Unset irrelevant variables.
|
|
deactivate nondestructive
|
|
|
|
set -gx VIRTUAL_ENV "__VENV_DIR__"
|
|
|
|
set -gx _OLD_VIRTUAL_PATH $PATH
|
|
set -gx PATH "$VIRTUAL_ENV/__VENV_BIN_NAME__" $PATH
|
|
|
|
# Unset PYTHONHOME if set.
|
|
if set -q PYTHONHOME
|
|
set -gx _OLD_VIRTUAL_PYTHONHOME $PYTHONHOME
|
|
set -e PYTHONHOME
|
|
end
|
|
|
|
if test -z "$VIRTUAL_ENV_DISABLE_PROMPT"
|
|
# fish uses a function instead of an env var to generate the prompt.
|
|
|
|
# Save the current fish_prompt function as the function _old_fish_prompt.
|
|
functions -c fish_prompt _old_fish_prompt
|
|
|
|
# With the original prompt function renamed, we can override with our own.
|
|
function fish_prompt
|
|
# Save the return status of the last command.
|
|
set -l old_status $status
|
|
|
|
# Output the venv prompt; color taken from the blue of the Python logo.
|
|
printf "%s%s%s" (set_color 4B8BBE) "__VENV_PROMPT__" (set_color normal)
|
|
|
|
# Restore the return status of the previous command.
|
|
echo "exit $old_status" | .
|
|
# Output the original/"old" prompt.
|
|
_old_fish_prompt
|
|
end
|
|
|
|
set -gx _OLD_FISH_PROMPT_OVERRIDE "$VIRTUAL_ENV"
|
|
end
|