erg/doc/JA/tips.md

Tips

エラーの表示言語を変えたい

各国語版のergをダウンロードしてください。 ただし、標準ライブラリ以外では多言語対応がなされていない可能性があります。

レコードの特定の属性だけ可変化したい

record: {.name = Str; .age = Nat; .height = CentiMeter}
{height; *rest} = record
mut_record = {.height = !height; *rest}

変数のシャドーイングがしたい

Ergで同一スコープ内でのシャドーイングはできません。しかし、スコープが変われば定義しなおせるので、インスタントブロックを使うといいでしょう。

# T!型オブジェクトを取得し、最終的にT型として変数へ代入する
x: T =
    x: T! = foo()
    x.bar!()
    x.freeze()

final class(継承不能クラス)を何とかして再利用したい

ラッパークラスを作りましょう。これはいわゆるコンポジション(合成)と言われるパターンです。

FinalWrapper = Class {inner = FinalClass}
FinalWrapper.
    method self =
        self::inner.method()
    ...

1始まりでenumerateしたい

method 1:

arr = [...]
for! arr.iter().enumerate(start := 1), i =>
    ...

method 2:

arr = [...]
for! arr.iter().zip(1..), i =>
    ...

非公開APIを(ホワイトボックス)テストしたい

foo.erの非公開APIはfoo.test.erというモジュールでは特別にアクセス可能となります。 foo.test.erモジュールはインポートできないので、隠蔽性は保たれます。

# foo.er
private x = ...

# foo.test.er
foo = import "foo"

@Test
'testing private' x =
    ...
    y = foo::private x
    ...

外部からはread-onlyな(可変)属性を定義したい

属性をプライベートにして、ゲッタを定義するとよいでしょう。

C = Class {v = Int!}
C::
    inc_v!(ref! self) = self::v.inc!()
    ...
C.
    get_v(ref self): Int = self::v.freeze()
    ...

トレイトのメソッドを実装する際に、使わなかった変数の警告が出る

discardまたは_ = ...を使うとよいでしょう。

T = Trait {.f = (Self, x: Int, s: Str) -> Int}

C = Class T
C|<: T|.
    f self, x, s =
        discard s # or _ = s
        ...

警告を出さないようにしたい

Ergに警告を止めるオプションはありません(これは意図的な設計です)。コードを修正してください。